La fonction Recherche et Remplacement en VBA

Permet de spécifier la police de caractères à rechercher. Comme c'est l'objet Font qui est utilisé, toutes les propriétés de cette police peuvent être utilisées.

Selection.HomeKey unit:=wdStory

    With Selection.Find
        .ClearFormatting
        With .Font
            .Bold = True
            .Name = "Arial"
        End With
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

Dans ce code, nous recherchons le mot "auctor" qui est écrit en gras et en Arial. Le Debug.Print devant la propriété .Found permet d'afficher le résultat de la recherche dans la fenêtre d'exécution.

Le Debug.Print inséré devant la méthode .Execute aurait eu le même résultat. La seule différence est que .Found peut être utilisé un grand nombre de fois, alors que .Execute lancera la recherche chaque fois qu'elle sera appelée.

Cette propriété spécifie si le format du texte doit être pris en compte pour exécuter la recherche. Si l'on prend l'exemple précédent, cette propriété doit être placée après le .Font, placée avant, elle n'aura aucun effet.

Si elle est utilisée avec une valeur False, le format ne sera pas pris en compte.

Selection.HomeKey unit:=wdStory

    With Selection.Find
        .ClearFormatting
        With .Font
            .Bold = True
            .Name = "Arial"
        End With
        .Format = True
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

Elle est surtout intéressante si vous souhaitez dialoguer avec l'utilisateur pour prendre ses choix en compte.

Cette propriété indique à la fonction si la recherche doit se faire du début à la fin du document ou inversement. La valeur par défaut est True.

With Selection.Find
    .Forward = True
    .Text = "auctor"
    .Execute
End With

Si vous souhaitez commencer la recherche par le début du document, vous devrez insérer :
Selection.HomeKey Unit:=wdStory

Cette propriété est très importante si vous souhaitez utiliser le résultat de votre recherche. C'est le cas si vous effectuez une boucle basée sur ce résultat.

    With Selection.Find
        .ClearFormatting
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

Si la recherche est fructueuse, vous aurez l'affichage True dans la fenêtre d'exécution (Debug.Print .Found).

Permet de rechercher un texte surligné lors qu'elle est à True.

    With Selection.Find
        .ClearFormatting
        .Highlight = True 'Recherche d'un texte surligné
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

Dans l'exemple ci-dessus, c'est ce mot surligné en rouge qui sera trouvé par la recherche.

Cette propriété lorsqu'elle est True permet d'ignorer la ponctuation dans une recherche. Si le texte recherché se trouve dans le document mais séparé par un signe de ponctuation, il sera trouvé.

    With Selection.Find
        .ClearFormatting
        .IgnorePunct = True
        .Forward = True
        .Text = "sapien auctor"
        .Execute
        Debug.Print .Found
    End With

Dans l'exemple ci-dessus, les textes suivants seront trouvés par la recherche : "sapien auctor" ainsi que "sapien. auctor", bien que ces deux mots soient séparés dans le second cas par un signe de ponctuation.

Cette propriété permet de rechercher des expressions dans un document, même si elles contiennent un ou plusieurs espaces consécutifs.

    With Selection.Find
        .ClearFormatting
        .IgnoreSpace = True
        .Forward = True
        .Text = "sapienauctor"
        .Execute
        Debug.Print .Found
    End With

Dans l'exemple ci-dessus, le texte suivant sera trouvé par la recherche : "sapien auctor".

Permet de limiter la recherche à une langue. Cette propriété prend comme argument une constante wdLanguageId.

    With Selection.Find
        .ClearFormatting
        .LanguageId = wdBelgianDutch
        .Forward = True
        .Text = "sapienauctor"
        .Execute
        Debug.Print .Found
    End With

Pour certaines langues, il est important d'identifier clairement la langue d'édition. Pour la Belgique, nous avons wdBelgianDutch et wdBelgianFrench qui sont tous deux différents de wdDutch et wdFrench.

Propriété très intéressante. Elle permet de trouver toutes les formes d'un même mot. Prenons l'exemple de cheval qui au pluriel devient chevaux. Si cette propriété est utilisée, lors de la recherche de "cheval", "chevaux" sera également trouvé.

    With Selection.Find
        .ClearFormatting
        .MatchAllWordForms = True
        .Forward = True
        .Text = "cheval"
        .Execute
        Debug.Print .Found
    End With

C'est valable pour les pluriels, les formes conjuguées d'un verbe, si vous recherchez "être", vous trouverez toutes ses formes conjuguées : "suis", "es"\x{0085}

Dans l'interface graphique il est précisé que cette option ne fonctionne que pour la langue anglaise, mais il n'en est rien, elle fonctionne aussi en français, mais pas efficacement.

Alors que cette propriété fonctionne très bien pour l'anglais, ses résultats sont très mitigés pour la langue française.

Cette propriété permet la distinction entre les majuscules et les minuscules.

    With Selection.Find
        .ClearFormatting
        .MatchCase = True
        .Forward = True
        .Text = "Cheval"
        .Execute
        Debug.Print .Found
    End With

Dans cet exemple, seul Cheval écrit avec une majuscule sera trouvé.

Cette propriété permet de retrouver une phrase en omettant les signes de ponctuation, les espaces...

    With Selection.Find
        .ClearFormatting
        .MatchPhrase = True
        .Forward = True
        .Text = "un animal qui appartient"
        .Execute
        Debug.Print .Found
    End With

Dans l'exemple ci-dessus, votre recherche aboutira aussi pour "un animal, qui appartient".

La traduction de cette propriété est "sonne comme", ce qui signifie que l'on va retrouver les homophones du texte.

    With Selection.Find
        .ClearFormatting
        .MatchSoundsLike = True
        .Forward = True
        .Text = "home"
        .Execute
        Debug.Print .Found
    End With

Dans la phrase "Cet homme habite ce home", seront trouvés "homme" et "home".

Dans l'interface graphique il est précisé que cette option ne fonctionne que pour la langue anglaise, mais il n'en est rien, elle fonctionne aussi en français, mais les résultats sont assez décevant pour le français.

Cette option va limiter la recherche au mot entier, les portions de mots seront ignorées.

    With Selection.Find
        .ClearFormatting
        .MatchWholeWord = True
        .Forward = True
        .Text = "hom"
        .Execute
        Debug.Print .Found
    End With

Dans la phrase "Cet homme habite ce home", la recherche sera infructueuse.

Si vous souhaitez utiliser des caractères génériques dans vos recherches, cette propriété doit être True.

Le plus connu de ces caractères génériques est l'étoile "*". Ce caractère représente, lorsqu'il est utilisé, un ou plusieurs caractères.

Si vous utilisez pour votre recherche "i*m", vous obtiendrez comme résultat : ipsum; icies, purus lectus m\x{0085} En fait, toutes les combinaisons possibles dans votre document commençant par un "i" et se terminant par un "m", que ces lettres soient ou non dans un même mot. Au point que si vous prenez la première et la dernière lettre de votre texte, vous aurez un résultat contenant tout votre texte.

    With Selection.Find
        .Text = "i*m"
        .Forward = True
        .MatchWildcards = True
        .Execute
    End With

Si cette propriété n'est pas True, pour la même recherche, les seuls résultats qui seront fructueux seront les mots de trois lettres suivants : "i*m".

Cette propriété, lorsqu'elle est True, ignore dans la recherche les mots trouvés fautifs par le vérificateur d'orthographe ou de grammaire.

    With Selection.Find
        .Text = "i*m"
        .Forward = True
        .NoProofing = True
        .Execute
    End With

Permet de faire une recherche sur des propriétés précises d'un paragraphe comme son niveau, son espacement\x{0085}

    With Selection.Find
        .Forward = True
        .ParagraphFormat.OutlineLevel = wdOutlineLevel3    'Recherche sur un niveau 3
        .Execute
    End With

Si vous exécutez une recherche sur un format de paragraphe, la propriété .Text peut être omise.

Cette propriété permet, lorsqu'elle est utilisée, de remplacer le mot recherché par celui qui lui est passé en argument. Cette propriété peut en recevoir d'autres en argument.

Si vous souhaitez que la police du mot trouvé change, c'est en argument que vous devez le spécifier.

    With Selection.Find
        .Text = "Mon texte à chercher"
        .Replacment.Text = "Mon texte de remplacement"
        .ClearFormating
        .Execute
    End With

Si dans votre remplacement, vous souhaitez modifier le format du texte, le surligner en rouge, c'est avec cette propriété que vous devez le faire.

Style permet de faire une recherche sur une portion de texte avec un style précis.

    With Selection.Find
        .Text = "auctor"
        .Style = "Normal"
        .Forward = True
        .NoProofing = True
        .Execute
    End With

Cette propriété reçoit comme argument le texte qui sera recherché.

    With Selection.Find
        .Text = "auctor"
        .Forward = True
        .NoProofing = True
        .Execute
    End With

Cette propriété permet de définir si la recherche n'a pas commencé au début du document, si elle doit reprendre dès le début quand la fin du texte est atteinte.

.Wrap = wdFindStop

Cette propriété peut prendre trois valeurs en argument wdFindStop, wdFindAsk et wdFindcontinue qui auront comme résultat l'arrêt à la fin du document, une demande à l'utilisateur ou continuer depuis le début.

Cette méthode est utilisée pour supprimer le formatage du texte de la recherche ou du remplacement.

Selection.HomeKey unit:=wdStory

    With Selection.Find
        .ClearFormatting
        With .Font
            .Bold = True
            .Name = "Arial"
        End With
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

Dans l'exemple ci-dessus, nous cherchons un texte qui serait écrit avec la police de caractère Arial.

Si nous lançons une seconde recherche :

Selection.HomeKey unit:=wdStory

    With Selection.Find
        .ClearFormatting
        With .Font
            .Italic = True
        End With
        .Forward = True
        .Text = "auctor"
        .Execute
        Debug.Print .Found
    End With

La recherche ne sera fructueuse que pour le mot "auctor" qui sera écrit en Arial gras et italique. Les paramètres de formatage de la recherche précédente restent en "mémoire" et faussent le résultat. En utilisant .ClearFormatting, vous "videz la mémoire".

Cette méthode doit être utilisée tant pour la recherche que pour le remplacement.

With Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
End With
….
….
….

Cette méthode est la plus importante. Sous Word 2010 et 2007 on retrouve une méthode Execute2007 qui est semblable à la méthode Execute.

Elle va exécuter la recherche demandée. Cette méthode renvoie True si la recherche est couronnée de succès. Avec cette méthode, vous pouvez passer directement les arguments à la fonction.

Sub RechercherUnMot()
    MsgBox Selection.Find.Execute (FindText:="Olivier")
End Sub

Si votre texte contient le mot "Olivier", vous aurez une boîte de message avec comme texte "True".

Elle peut prendre un argument qui est important dans le cas d'un remplacement.

With Selection.Find
    .Text = "Moi"
    .Replacement.Text = "Toi"
    .Execute Replace:=wdReplaceAll
End With

En argument, si vous souhaitez faire un remplacement, vous devrez utiliser : Replace. Elle peut recevoir trois valeurs, qui sont des constantes : wdReplaceAll; wdReplaceOne et wdReplaceNone.

Dans un premier temps, nous allons ouvrir les deux documents, le premier contenant la liste des mots à rechercher (tableau à deux colonnes) et le second étant celui dans lequel nous souhaitons faire les remplacements.

Pour ouvrir les documents, au lieu de les mettre en "dur" dans le code, nous allons utiliser un objet "FileDialog". Cet objet permet de sélectionner un répertoire ou un fichier. Dans notre exemple, nous allons l'utiliser pour les fichiers. Ce choix s'obtient par l'argument passé lors de l'affectation.

Set oDlg = Application.FileDialog(msoFileDialogFilePicker)

Pour afficher cette boîte de dialogue, nous allons utiliser sa méthode ".Show".

Comme il s'agit d'un échange avec l'utilisateur, nous avons la possibilité de choisir un titre pour la boîte de dialogue et nous n'avons besoin que d'un seul fichier.

With oDlg
    'Pour un seul fichier la valeur sera False
    .AllowMultiSelect = False
    .Title = "Document contenant le tableau"
    .Show
End With

Cet objet va renvoyer le nom du fichier choisi par l'utilisateur. Comme il n'y a qu'un seul fichier, nous récupérons le premier élément.

oDlg.SelectedItems(1)

Il n'est pas nécessaire de passer par une variable, nous pouvons directement utiliser le résultat en argument.

Que ce soit pour le document source ou le document cible, la méthode d'ouverture du document est toujours la même.

Set oDocSource = Documents.Open(oDlg.SelectedItems(1))

Il ne nous reste que la boucle sur les éléments du tableau qui seront utilisés pour la recherche et le remplacement. On affecte le premier tableau du document source à la variable tableau pour ensuite faire une boucle sur les lignes du tableau. Dans notre cas, c'est assez simple, la première colonne contient le mot à rechercher et la seconde, le mot de remplacement.

Set oTbl = oDocSource.Tables(1)
'Boucle sur les cellules de la table
For Each oRow In oTbl.Rows
        'Sélection du document cible
        oDocCible.Select
            Selection.HomeKey unit:=wdStory
            With Selection.Find
                .ClearFormatting
                .Forward = True
                .Text = NetText(oRow.Cells(1).Range.Text)   'utilisation de notre fonction
                .Replacement.Text = NetText(oRow.Cells(2).Range.Text)   'utilisation de notre fonction
                .Replacement.ClearFormatting
                .Execute Replace:=wdReplaceAll
            End With
    
Next oRow

Dans cette boucle, nous utilisons directement le résultat dans notre fonction de recherche et remplacement.

            With Selection.Find
                .ClearFormatting
                .Forward = True
                .Text = NetText(oRow.Cells(1).Range.Text)   'utilisation de la fonction de nettoyage
                .Replacement.Text = NetText(oRow.Cells(2).Range.Text)   'utilisation de la fonction de nettoyage
                .Replacement.ClearFormatting
                .Execute Replace:=wdReplaceAll
            End With

Voici le code complet :

Sub RemplacerListeDeMots()
'-------------------------------------------------
'Cette macro a pour rôle de remplacer les mots d'un
' document par une liste de
'mots se trouvant dans une table à deux colonnes
'-------------------------------------------------
'Déclaration des variables
'Le document oDocSource , contient la
'liste des mots et le document oDocCible les mots
'à remplacer
Dim oDocSource As Document, oDocCible As Document
'Déclaration des variables table
Dim oTbl As Table
Dim oRow As Row
'Une boîte de dialogue pour choisir les documents
Dim oDlg As FileDialog

'Ouverture du premier document
'Affectation de l'objet oDlg
Set oDlg = Application.FileDialog(msoFileDialogFilePicker)
'Ouverture de la boîte de dialogue
With oDlg
    .AllowMultiSelect = False
    .Title = "Document contenant le tableau"
    .Show
End With
'La propriété SelectedItems contient
Set oDocSource = Documents.Open(oDlg.SelectedItems(1))
'Il faut répéter l'opération une seconde fois pour le
'document cible
With oDlg
    .AllowMultiSelect = False
    .Title = "Document avec remplacement"
    .Show
End With
'ouverture du second document
Set oDocCible = Documents.Open(oDlg.SelectedItems(1))
'Affectation de la table
Set oTbl = oDocSource.Tables(1)
'Boucle sur les cellules de la table
For Each oRow In oTbl.Rows
        'Sélection du document cible
        oDocCible.Select
            Selection.HomeKey unit:=wdStory
            With Selection.Find
                .ClearFormatting
                .Forward = True
                .Text = NetText(oRow.Cells(1).Range.Text)   'utilisation de notre fonction
                .Replacement.Text = NetText(oRow.Cells(2).Range.Text)   'utilisation de notre fonction
                .Replacement.ClearFormatting
                .Execute Replace:=wdReplaceAll
            End With
    
Next oRow
'Libération des objets
Set oDlg = Nothing
Set oTbl = Nothing
oDocSource.Close savechanges:=wdDoNotSaveChanges
Set oDocSource = Nothing


End Sub

Ces deux codes sont à placer dans le Normal.Dotm pour qu'ils soient disponibles pour toutes vos recherches. La fonction de nettoyage des caractères de fin de cellule peut être réutilisée dans d'autres codes.